Triage top heavy targets in DTB from telemetry

Provided by @davkean - the top targets by impact on Design Time Build from the project system telemetry data:

```
let eventCount = 10000;
RawEventsVSInternal
| where AdvancedServerTimestampUtc > ago(30d)
| where EventName endswith "designtimebuildcomplete"
| sample eventCount
| project LegacyTargetsList = tostring(Properties["vs.vsproject.langbuild.designtimebuildcomplete.targets"]),
CPSTargetsList = replace_string(tolower(tostring(Properties["vs.projectsystem.managed.designtimebuildcomplete.targets"])), '-', '')
| project TargetsList = iif(isempty(LegacyTargetsList), CPSTargetsList, LegacyTargetsList)
| where TargetsList != ""
| project TargetRunTimes = split(TargetsList, ';')
| mv-expand TargetRunTimes
| where TargetRunTimes != ""
| project TargetWithRuntime=split(TargetRunTimes, ':')
| project Name=tostring(TargetWithRuntime[0]), TimeInMs=todouble(TargetWithRuntime[1])
| where not(isnull(TimeInMs))
| summarize Count = count(), percentiles(TimeInMs, 25, 50, 75, 95) by Name
| extend EventPercentage = (toreal(Count) / eventCount) * 100
| extend Score = get_failure_score(EventPercentage, percentile_TimeInMs_25, percentile_TimeInMs_50, percentile_TimeInMs_75, percentile_TimeInMs_95 )
| order by Score
| take 10
| project ["Name (hashed)"]=Name,
["Score"] = round(Score),
["% Events"] = round(EventPercentage),
["25th Percentile"]=round(percentile_TimeInMs_25),
["50th Percentile"]=round(percentile_TimeInMs_50),
["75th Percentile"]=round(percentile_TimeInMs_75),
["90th Percentile"]=round(percentile_TimeInMs_95)
```

Name (hashed) | Score | % Events | 25th Percentile | 50th Percentile | 75th Percentile | 90th Percentile
-- | -- | -- | -- | -- | -- | --
_getprojectreferencetargetframeworkproperties | 51,061 | 55 | 33 | 303 | 1,002 | 4,987
resolveprojectreferences | 44,493 | 46 | 15 | 90 | 1,088 | 6,352
blockutilitypackagereferenceinxappackages | 30,419 | 27 | 556 | 646 | 816 | 1,649
blocknonxaputilitypackagereference | 29,056 | 27 | 517 | 619 | 814 | 1,579
xapcodegenworkflow | 7,933 | 4 | 678 | 1,009 | 1,519 | 5,369
xapcodegenplugin | 5,256 | 3 | 377 | 1,124 | 1,344 | 7,446
resolvepackageassets | 5,133 | 60 | 17 | 47 | 98 | 247
mscoveragereferencedpathmaps | 4,926 | 3 | 51 | 403 | 2,016 | 9,546
xapcopyresourcefolders | 4,876 | 9 | 43 | 93 | 631 | 3,027
resolveassemblyreferences | 4,128 | 69 | 19 | 33 | 56 | 144

More details in the chat: https://teams.microsoft.com/l/message/19:304b262594b14232ba611060b90a73d2@thread.v2/1739961604195?context=%7B%22contextType%22%3A%22chat%22%7D